function textinput(name, value) {
	return "<input type=\"text\" name=\"" name "\" value=\"" value "\" />"
}

function hidden(name, value) {
	return "<input type=\"hidden\" name=\"" name "\" value=\"" value "\" />"
}

function button(name, caption) {
	return "<input type=\"submit\" name=\"" name "\" value=\"@TR<<" caption ">>\" />"
}

function sel_option(name, caption, default, sel) {
	if (default == name) sel = " selected=\"selected\""
	else sel = ""
	return "<option value=\"" name "\"" sel ">@TR<<" caption ">></option>"
}

function close_field() {
	if (field_open == 1) print "</td></tr></table><div style=\"clear:both; height: 5pt;\">&nbsp;</div>"
	field_open = 0
}

BEGIN {
	FS="|"
}

# trim leading whitespaces
{
	gsub(/^[ \t]+/,"",$1)
}

$1 ~ /^onchange/ {
	onchange = $2
}

($1 != "") && ($1 !~ /^option/) && (select_open == 1) {
	select_open = 0
	printf "</select>"
}

$1 ~ /^infotext/ {
	close_field()
	print "<p >@TR<<" $2 ">></p>"
}


#
# Table issues
#

$1 ~/^infotable/ {
	close_field()
	print "<p class=\"tableText\">@TR<<" $2 ">></p>"
}

#
# Table title 
#
$1 ~/^tabletitle/ {
        close_field()
        print "<h2>@TR<<" $2 ">></h2>"
}

#
# $2: the summary of the table.
#

$1 ~ /^start_table/ {
	close_field()
	print "<TABLE border=\"" $2  "\" cellspacing=\"" $3 "\" cellpadding=\"" $4 "\" summary=\"" $5 "\">"
}

$1 ~ /^start_border_table/ {
	close_field()
	print "      <table class=\"data_table\" border=\"0\" cellspacing=\"0\" cellpadding=\"0\">"
}

$1 ~ /^end_border_table/ {
	close_field()
	print " 	</table> "
}

$1 ~ /^end_table/ {
	close_field()
	print "</TABLE>"
}

#
# $2: The title of the table
#
$1 ~ /^table_caption/ {
	close_field()
	print "<caption>" $2 "</caption>"
}

#
# Begins a new row to the table
#
$1 ~ /^add_row/ {
	close_field()
	print "<TR>"
}


$1 ~ /^end_row/ {
	close_field()
	print "</TR>"
}
#
# Add a cell to the row:
#	$2: height of the row
#	$3: width of the row
#	$4: text of the row
$1 ~ /^add_title_cell/ {
	close_field()
	print "<th>@TR<<" $2 ">></th>"
}

$1 ~ /^add_normal_cell/ {
	close_field()
	print "<TD bgcolor=\"ffffff\" class=\"tableText\">" $2 "</TD>" 
}

$1 ~ /^add_data_cell/ {
        close_field()
        print "<td>" $2 "</td>"
}


$1 ~ /^add_label_cell/ {
        close_field()
        print "<TD valign=\"middle\" class=\"tableText\"><label for='"$3"'> " $2 "</label></TD>"
}

$1 ~ /^add_pass_cell/ {
	close_field
	print "<TD class=\"tableText\">"
	print "<input id=\"" $2 "\" valign=\"middle\" type=\"password\" name=\"" $2 "\" class=\"" $3 "\" value=\"" $4 "\"/>" $5
	print "</TD>"
}

$1 ~ /^start_select_cell/ {
	opts = ""
        if (onchange != "") opts = opts " onChange=\"" onchange "()\""
	print "<TD class=\"tableText\">"
        print "<select id=\"" $2 "\" valign=\"middle\" name=\"" $2 "\" class=\"" $4 "\"" opts ">"
        select_id = $2
        select_open = 1
	select_default = $3
}

$1 ~ /^end_select_cell/ {
	close_field()
	print " </select></td>"
}

$1 ~ /^add_input_cell/ {
	print "<TD class=\"tableText\">"
	print "<input id=\"" $2 "\" valign=\"middle\" type=\"text\" name=\"" $2 "\" value=\"" $3 "\" class=\"" $4 "\"/>" $5
	print "</TD>"
	
}

$1 ~ /^add_button_cell/ {
	close_field()
	print "<TD class=\"tableText\">"
        print "<input type=\"submit\" name=\"" $2 "\" value=\"" $3  "\" class=\"plain_button_orange\" />"
	print "</TD>"
	
}

$1 ~ /^add_check_cell/ {
	opts=""
        if (onchange != "") opts = opts " onClick=\"" onchange "()\" onChange=\"" onchange "()\""
	print "<TD class=\"tableText\">"$3
        print "<input id=\"" $2  "\" type=\"checkbox\" name=\"" $2 "\"  " opts " class=\"" $4 "\"/>"
	print "</TD>"
}

# Draw a line
$1 ~ /^draw_line/ {
	close_field()
	print "<tr><td colspan=\"2\"><hr /></td></tr>"
}

$1 ~ /^start_div/ {
	close_field()
	print "<div id=\"" $2 "\">"
}

$1 ~ /^end_div/ {
	close_field()
	print "</div>"
}

$1 ~ /^field/ {
	close_field()
	print "<label>@TR<<" $2 ">></label><table><tr><td>"
	field_open=1
}
$1 ~ /^checkbox/ {
	if ($3==$4) opts="checked=\"checked\" "
	else opts=""
	if (onchange != "") opts = opts " onClick=\"" onchange "()\" onChange=\"" onchange "()\""
	print "<input id=\"" $2 "_" $4 "\" type=\"checkbox\" name=\"" $2 "\" value=\"" $4 "\" " opts " />"
}
$1 ~ /^radio/ {
	if ($3==$4) opts="checked=\"checked\" "
	else opts=""
	if (onchange != "") opts = opts " onClick=\"" onchange "()\" onChange=\"" onchange "()\""
	print "<input id=\"" $2 "_" $4 "\" type=\"radio\" name=\"" $2 "\" value=\"" $4 "\" " opts " />"
}
$1 ~ /^select/ {
	opts = ""
	if (onchange != "") opts = opts " onChange=\"" onchange "()\""
	print "<select id=\"" $2 "\" name=\"" $2 "\"" opts ">"
	select_id = $2
	select_open = 1
	select_default = $3
}
($1 ~ /^option/) && (select_open == 1) {
	if ($2 == select_default) option_selected=" selected=\"selected\""
	else option_selected=""
	if ($3 != "") option_title = $3
	else option_title = $2
	print "<option id=\"" select_id "_" $2 "\"" option_selected " value=\"" $2 "\">" option_title "&nbsp;&nbsp;</option>"
}

$1 ~ /^caption/ { print "<b>" $2 "</b>" }
$1 ~ /^string/ { print $2 }
$1 ~ /^text/ { print "<input id=\"" $2 "\" type=\"text\" name=\"" $2 "\" value=\"" $3 "\" />" $4 }
$1 ~ /^password/ { print "<input id=\"" $2 "\" type=\"password\" name=\"" $2 "\" value=\"" $3 "\" />" $4 }
$1 ~ /^submit/ {
	close_field()
	print "<input type=\"submit\" name=\"" $2 "\" value=\"" $3  "\" class=\"plain_button_orange\" />"
}

($1 ~ /^checkbox/) || ($1 ~ /^radio/) {
	print $5
}

END {
	close_field()
}