###
 #
 # FreeWLAN Addons - http://www.freewlan.info
 #
 # This Script is based on the original La Fonera Firmware version 0.7.1r2
 #
 # This program is free software; you can redistribute it and/or
 # modify it under the terms of the GNU General Public License
 # as published by the Free Software Foundation; either version 2
 # of the License, or (at your option) any later version.
 #
 # This program is distributed in the hope that it will be useful,
 # but WITHOUT ANY WARRANTY; without even the implied warranty of
 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 # GNU General Public License for more details.
 #
 # You should have received a copy of the GNU General Public License
 # along with this program; if not, write to the Free Software
 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston,
 # MA  02110-1301, USA
 #
 # http://www.gnu.org/copyleft/gpl.html
 #
###

function textinput(name, value) {
	return "<input type=\"text\" name=\"" name "\" value=\"" value "\" />"
}

function fileinput(name, value) {
	return "<input type=\"file\" name=\"" name "\" value=\"" value "\" />"
}

function hidden(name, value) {
	return "<input type=\"hidden\" name=\"" name "\" value=\"" value "\" />"
}

function button(name, caption) {
	return "<input type=\"submit\" name=\"" name "\" value=\"@TR<<" caption ">>\" />"
}

function sel_option(name, caption, default, sel) {
	if (default == name) sel = " selected=\"selected\""
	else sel = ""
	return "<option value=\"" name "\"" sel ">@TR<<" caption ">></option>"
}

function close_field() {
	if (field_open == 1) print "</td></tr></table><div style=\"clear:both; height: 5pt;\">&nbsp;</div>"
	field_open = 0
}

BEGIN {
	FS="|"
}

# trim leading whitespaces
{
	gsub(/^[ \t]+/,"",$1)
}

$1 ~ /^onchange/ {
	onchange = $2
}

($1 != "") && ($1 !~ /^option/) && (select_open == 1) {
	select_open = 0
	printf "</select>"
}

$1 ~ /^infotext/ {
	close_field()
	print "<p >@TR<<" $2 ">></p>"
}

$1 ~ /^add_form/ {
	print "<form method=\"POST\" name=\"" $2 "\" action=\"" $3 "\" enctype=\"multipart/form-data\" onSubmit=\"" $4 "()\">"
}

$1 ~ /^end_form/ {
	print "</form>"
}

#
# Table issues
#

$1 ~/^infotable/ {
	close_field()
	print "<p class=\"tableText\"><b>@TR<<" $2 ">></b></p>"
}

#
# $2: the summary of the table.
#

$1 ~ /^start_table/ {
	print "<TABLE border=\"" $2  "\" cellspacing=\"" $3 "\" cellpadding=\"" $4 "\" summary=\"" $5 "\">"
	print "<colgroup><col width=\"150\"><col width=\"\"><col width=\"150\"></colgroup>"
}

$1 ~ /^start_radio_table/ {
	print "<TABLE border=\"" $2  "\" cellspacing=\"" $3 "\" cellpadding=\"" $4 "\" summary=\"" $5 "\">"
}

$1 ~ /^start_border_table/ {
	close_field()
	print " <tr><td bgcolor=\"FADCBF\">"
	print "  <table border=\"0\" cellspacing=\"0\" cellpadding=\"1\">"
	print "  <tr><td>"
	print "      <TABLE border=\"0\" cellspacing=\"0\" cellpadding=\"0\">"
}

$1 ~ /^end_border_table/ {
	close_field()
	print " 	</TABLE> "
	print "  </td></tr> "
	print "  </table> "
	print " </td> </tr> " 
}

$1 ~ /^end_table/ {
	close_field()
	print "</TABLE>"
}

#
# $2: The title of the table
#
$1 ~ /^table_caption/ {
	close_field()
	print "<tr><td ALIGN=\"CENTER\" class=\"tableText\"><EM>" $2 "</EM></TD></tr>"
}

#
# Begins a new row to the table
#
$1 ~ /^add_row/ {
	close_field()
	print "<TR>"
}

$1 ~ /^end_row/ {
	close_field()
	print "</TR>"
}
#
# Add a cell to the row:
#	$2: height of the row
#	$3: width of the row
#	$4: text of the row
$1 ~ /^add_title_cell/ {
	close_field()
	print "<TD class=\"tableText Bold\">"$2"</TD>"
}

$1 ~ /^add_normal_cell/ {
	close_field()
	#print "<TD bgcolor=\"ffffff\" class=\"tableText\">" $2 "</TD>" 
	print "<TD nowrap class=\"tableText\">" $2 "</TD>" 
}

$1 ~ /^add_label_cell/ {
	close_field()
	if ($3 != "") print "<td nowrap class=\"tableText\" valign=\"top\">" $2 "</td><td align=right class=\"tableText\" valign=top>" $3 "</td>"
	else print "<TD nowrap class=\"tableText\" valign=\"top\">" $2 "</TD>"
}
$1 ~ /^add_checkbox_cell/ {
	print "<TD class=\"tableText\" align=\"middle\">"$3
	if ($5 != "") print "<input class=\"checkbox\" id=\"" $2 "\" type=\"checkbox\" name=\"" $2 "\" value=\"" $4 "\" onChange=\"" $5 "()\">"
	else print "<input class=\"checkbox\" id=\"" $2 "\" type=\"checkbox\" name=\"" $2 "\" value=\"" $4 "\">"
	print "</TD>"
}

$1 ~ /^add_radio_cell/ {
    close_field()
	if ($3==$4) opts="checked=\"checked\" "
	else opts=""
	if (onchange != "") opts = opts " onClick=\"" onchange "()\" onChange=\"" onchange "()\""
	print "<TD class=\"tableText\">"$3
	print "<input class=\"radio\" id=\"" $2 "_" $4 "\" type=\"radio\" name=\"" $2 "\" value=\"" $4 "\" " opts " />"
	print "</TD>"
}

$1 ~ /^add_fileinput_cell/ {
	print"  <td>"
	print    fileinput($2,$3)
	print"  </td>"
}

$1 ~ /^add_pass_cell/ {
	close_field
	print "<TD class=\"tableText\">"
	print "<input id=\"" $2 "\" valign=\"left\" type=\"password\" name=\"" $2 "\" value=\"" $3 "\" class=\"" $4 "\"/>" $5
	print "</TD>"
}

$1 ~ /^start_select_cell/ {
	print "<TD class=\"tableText\" valign=\"top\">"
        if ($5 != "") print "<select id=\"" $2 "\" valign=\"middle\" name=\"" $2 "\" class=\"" $4 "\" onChange=\"" $5 "()\">"
        else print "<select id=\"" $2 "\" valign=\"middle\" name=\"" $2 "\" class=\"" $4 "\">"
		select_id = $2
        select_open = 1
	select_default = $3
}

$1 ~ /^end_select_cell/ {
	close_field()
	print " </select></td>"
}

$1 ~ /^add_input_cell/ {
	print "<TD class=\"tableText\">"
	if ( $5 == "")	print "<input id=\"" $2 "\" valign=\"middle\" type=\"text\" name=\"" $2 "\" value=\"" $3 "\" class=\"" $4 "\"/>"
	if ( $5 != "")	print "<input id=\"" $2 "\" valign=\"middle\" type=\"text\" name=\"" $2 "\" value=\"" $3 "\" class=\"" $4 "\" onkeyup=\"" $5 "();\"/>"
	print "</TD>"
}

$1 ~ /^add_button_cell/ {
	print "<TD class=\"tableText\" align=\"middle\">"
	if ( $5 == "") 	print "	<input type=\"submit\" name=\"" $2 "\" value=\"" $3 "\" class=\"plain_button_orange\" />"
	if ( $5 != "")	print "	<input type=\"submit\" name=\"" $2 "\" value=\"" $3 "\" class=\"plain_button_orange\" onClick=\"" $5 "()\"/>"
	print "</TD>"
}

$1 ~ /^add_input_submit_button/ {
	print "<td><input id=\"form_submit\" type=\"submit\" name=\"" $2 "\" value=\"" $3 "\" onClick=\"" $4 "()\" class=\"tableTextButton\" /></td>"
}

$1 ~ /^add_download_button/ {
	print "<td><input type=\"button\" value=\"" $2 "\" onClick=\"" $3 "()\" class=\"tableTextButton\"></td>"
}

$1 ~ /^start_div/ {
	close_field()
	print "<div id=\"" $2 "\">"
}

$1 ~ /^end_div/ {
	close_field()
	print "</div>"
}

$1 ~ /^field/ {
	close_field()
	print "<label>@TR<<" $2 ">></label><table><tr><td>"
	field_open=1
}

$1 ~ /^select/ {
	opts = ""
	if (onchange != "") opts = opts " onChange=\"" onchange "()\""
	print "<select id=\"" $2 "\" name=\"" $2 "\"" opts ">"
	select_id = $2
	select_open = 1
	select_default = $3
}
($1 ~ /^option/) && (select_open == 1) {
	if ($2 == select_default) option_selected=" selected=\"selected\""
	else option_selected=""
	if ($3 != "") option_title = $3
	else option_title = $2
	print "<option id=\"" select_id "_" $2 "\"" option_selected " value=\"" $2 "\">" option_title "&nbsp;&nbsp;</option>"
}


$1 ~ /^help$/ {
	close_field()
	print "<div id=\"help\">"
	print "<a href=\"/cgi-bin/webif/help/" $2 ".sh\" rel=\"lyteframe\" rev=\"width: 450px; height: 550px\"><img src=\"/images/help.png\" alt=\"image_help\" border=\"0\" /> @TR<<Help>></a>"
	print "</div>"
}

$1 ~ /^help_topic/ {
	print "<p style=\"font-size: 11pt;\"><b>" $2 "</b></p>"
	
}

$1 ~ /^help_explanation/ {
	print "<p style=\"font-size: 10pt;\">" $2 "</p>"
}

$1 ~ /^add_au_select_branch/ {
	close_field();
	print("<td class=\"tableText\">");
	print("<select id=\"" $2 "\" valign=\"middle\" name=\"" $2 "\" class=\"" $4 "\">"); 
	print("<option value=\"stable\""); if( $3 == "stable" ) print(" selected=\"selected\""); print(">stable</option>");
	# We prolly don't have a connection, so print the selected one if it's not stable
	if ( $5 == "" && $3 != "stable" ) {
		print("<option value=\"" $3 "\" selected=\"selected\">" $3 "</option>");
	}
	for(i = 5; $(i) != ""; i++) {
		print("<option value=\"" $(i) "\""); if ( $(i) == $3 ) printf(" selected=\"selected\""); printf(">" $(i) "</option>");
	}
	print("</select></td>");
}

# to direct call a Javascript function
$1 ~ /^call_js/ {
	print "<script type=\"text/javascript\"> " $2 "(" $3 "); </script>"
}

# $2: webpage to load $3: services, reboot or [blank]
$1 ~ /^autoloadpage/ {
	print" <a href=\"/images/loading.gif\" rel=\"lytebox\" id=\"loading\"></a>"
	print" <script type=\"text/javascript\">"
	print"var timeoutID = null;"
	print" function loadLytebox(id) {"
	print"	if (typeof myLytebox != 'undefined') {"
	print"		myLytebox.start(document.getElementById(id));"
	print"	} else {"
	print"	if (timeoutID) { clearTimeout(timeoutID); }"
	print"        timeoutID = setTimeout('loadLytebox(\"'+id+'\")', 100);"
	print"    }"
	print"}"
	print"	loadLytebox('loading');"
	print" function call() {"
	print"	myLytebox.end();"
	print"	var URL = \"/cgi-bin/webif/" $2 ".sh\""
	print"	document.location.replace(URL);"
	print"}"
	if ( $3 == "services" ) { print"window.setTimeout(\"call()\", 35000);" }
	if ( $3 == "reboot" ) { print"window.setTimeout(\"call()\", 150000);" }
	if ( $3 == "" ) { print"window.setTimeout(\"call()\", 250);" }
	print"</script>"
}

END {
	close_field()
}